用51單片機(jī)對(duì)7113初始化和控制

　　SAA7113的初始化就是對(duì)寄存器配置合適的參數(shù)，使其能夠有符合要求的輸出。寄存器配置通過I2C總線來進(jìn)行，很多可以控制I2C總線的器件都可以作為主器件對(duì)7113進(jìn)行初始化，這里介紹用51單片機(jī)初始化7113的例子。

　　51單片機(jī)和7113的硬件連接非常簡單，只要把單片機(jī)的兩個(gè)I/O口(如P1.0、P1.0)直接和7113的SCL、SDA管腳相連，再加上上拉電阻即可。

　　用單片機(jī)初始化7113的主要任務(wù)是程序的編寫，首先要熟悉I2C總線協(xié)議，根據(jù)I2C總線的原理寫出啟動(dòng)、停止、應(yīng)答信號(hào)等的子程序，由子程序再寫出發(fā)送、接收1個(gè)字節(jié)的程序，然后根據(jù)7113的寄存器操作格式寫出讀寫寄存器的程序，最后根據(jù)以上的子程序?qū)懗龀跏蓟?113的程序段。

　　對(duì)7113的控制一般是改變色度、亮度等指標(biāo)以及輸出管腳的輸出信號(hào)，這可以通過修改相應(yīng)寄存器的值來完成，程序上寫出“讀寫命令”即可。

　　下面以程序段的形式給出初始化SAA7113以及讀寫寄存器的具體例子，以供參考。

　　SDA　BIT　P1.0

　　SCL　BIT　P1.1

　　I2C_ERROR　BIT　00H　;I2C總線數(shù)據(jù)傳輸出錯(cuò)標(biāo)志

　　DeviceaddressW　EQU　4AH　;7113器件地址+寫

　　DeviceaddressR　EQU　4BH　;7113器件地址+讀

　　Subaddress　EQU　4DH　;7113寄存器地址字節(jié)在單片機(jī)中的存放地址

　　DATA_I2C　EQU　50H　;設(shè)置寫入或讀出數(shù)據(jù)在單片機(jī)中的存放地址

　　;*************啟動(dòng)**************

　　I2C_START:　SETB　SDA

　　NOP

　　SETB　SCL

　　NOP

　　CLR　SDA

　　NOP

　　CLR　SCL

　　RET

　　;***************停止**************

　　I2C_STOP:　CLR　SDA

　　NOP

　　SETB　SCL

　　NOP

　　SETB　SDA

　　NOP

　　RET

　　;************送應(yīng)答位************

　　SEND_ACK:　CLR　SCL

　　NOP

　　CLR　SDA

　　NOP

　　SETB　SCL

　　NOP

　　?NOP

　　CLR　SCL

　　NOP

　　SETB　SDA

　　RET

　　;***********送非應(yīng)答位***********

　　SEND_NOACK: SETB　SDA

　　NOP

　　SETB　SCL

　　NOP

　　NOP

　　CLR　SCL

　　NOP

　　RET

　　;***********檢查應(yīng)答位************

　　CHECK_ACK: NOP

　　CLR　SCL

　　NOP

　　SETB　SDA

　　NOP

　　SETB　SCL

　　NOP

　　NOP

　　MOV　C, SDA

　　MOV　I2C_ERROR, C

　　CLR　SCL

　　NOP

　　RET

　　;*******發(fā)送1字節(jié)數(shù)據(jù)，待送數(shù)據(jù)在A中******

　　I2C_SEND_1BYTE:

　　MOV　R0, #8

　　SEND100: RLC　A

　　MOV　SDA,　C

　　NOP

　　SETB　SCL

　　NOP

　　NOP

　　CLR　SCL

　　DJNZ　R0, SEND100

　　RET

　　;*******接收1字節(jié)數(shù)據(jù)，接收數(shù)據(jù)放在A中*****

　　I2C_RECEIVE_1BYTE:

　　MOV　R0,　#8

　　RECV100:　SETB　SDA

　　NOP

　　SETB　SCL

　　NOP

　　NOP

　　NOP

　　MOV　C,　SDA

　　CLR　SCL

　　RLC　A

　　DJNZ　R0,　RECV100

　　RET

　　;*******通過I2C總線向某一寄存器寫入一個(gè)字節(jié)數(shù)據(jù)*********

　　I2C_WRITE:　ACALL　I2C_START　;發(fā)啟動(dòng)信號(hào)

　　MOV　A， # DeviceaddressW ;調(diào)7113地址+寫

　　ACALL　I2C_SEND_1BYTE　;發(fā)送7113地址及“寫”命令

　　ACALL　CHECK_ACK　;檢查7113的應(yīng)答信號(hào)

　　JNB　I2C_ERROR, WR200　;應(yīng)答正確，繼續(xù)

　　WR100:　ACALL　I2C_STOP　;應(yīng)答不對(duì)，返回

　　RET

　　WR200:　MOV　A, Subaddress　;調(diào)寄存器地址

　　ACALL　I2C_SEND_1BYTE　;發(fā)送寄存器地址

　　ACALL　CHECK_ACK　;檢查7113的應(yīng)答信號(hào)

　　JB　I2C_ERROR, WR100　;應(yīng)答不對(duì)，返回

　　MOV　A, DATA_I2C　;調(diào)準(zhǔn)備寫入的數(shù)據(jù)

　　ACALL　I2C_SEND_1BYTE　;發(fā)送數(shù)據(jù)字節(jié)

　　ACALL　CHECK_ACK

　　JB　I2C_ERROR, WR100

　　ACALL　I2C_STOP　;發(fā)停止信號(hào)

　　RET

　　;*******通過I2C總線讀出某一寄存器的數(shù)據(jù)*********

　　I2C_READ:　ACALL　I2C_START

　　MOV　A, # DeviceaddressW　;調(diào)7113地址，寫入

　　ACALL　I2C_SEND_1BYTE

　　ACALL　CHECK_ACK

　　JNB　I2C_ERROR, RD200

　　RD100:　ACALL　I2C_STOP

　　RET

　　RD200:　MOV　A, Subaddress　;調(diào)要讀的寄存器地址

　　ACALL　I2C_SEND_1BYTE　; 發(fā)送寄存器地址字節(jié)

　　ACALL　CHECK_ACK

　　JB　I2C_ERROR, RD100

　　ACALL　I2C_START　;重發(fā)起動(dòng)信號(hào)

　　MOV　A, # DeviceaddressR　;調(diào)7113地址，讀

　　ACALL　I2C_SEND_1BYTE

　　ACALL　CHECK_ACK

　　JB　I2C_ERROR, RD100

　　ACALL　I2C_RECEIVE_1BYTE ;接收讀出的數(shù)據(jù)

　　MOV　DATA_I2C,A　;讀出數(shù)據(jù)轉(zhuǎn)存

　　ACALL　SEND_NOACK　;發(fā)送非應(yīng)答位

　　ACALL　I2C_STOP　;停止

　　RET

　　;***************初始化7113，配置各寄存器************************

　　INIT_SAA7113:　MOV　DPTR, #SAA7113_Subaddress

　　MOV　R7, #28

　　INIT100:　MOV　A, #0

　　MOV　C A, @A+DPTR

　　MOV　Subaddress,　A　;調(diào)寄存器地址

　　MOV　A,#28

　　MOVC　A, @A+DPTR

　　MOV　DATA_I2C, A　;調(diào)寄存器配置數(shù)據(jù)

　　INC DPTR

　　ACALL　I2C_WRITE　;配置1個(gè)寄存器

　　JB　I2C_ERROR, INIT200

　　DJNZ　R7,INIT100

　　INIT200:　RET

　　;***************SAA7113寄存器初始化配置數(shù)據(jù)**********************

　　SAA7113_Subaddress:

　　DB 01H,02H,03H,04H,05H,06H,07H,08H,09H,0AH,0BH,0CH,0DH,0EH

　　DB 0FH,10H,11H,12H,13H,15H,16H,17H,40H,58H,59H,5AH,5BH,5EH

　　;共28個(gè)

　　I2C_REG_VALUE_AI11:

　　DB 08H,0C0H,33H,00H,00H,0EBH,0E0H,0B8H,01H,7EH,46H,43H,01H,01H

　　DB 0FH,00H,0CH,0A7H,00H,00H,00H,00H,02H,00H,54H,07H,80H,00H

　　;*************對(duì)SAA7113某一寄存器的改寫與讀出*******************

　　WRITE_READ:　MOV　Subaddress, #0AH　; 設(shè)寄存器地址為0AH

　　MOV　DATA_I2C, #88H　;改寄存器的值為88H

　　ACALL　I2C_WRITE　;改寫

　　ACALL　I2C_READ　;讀出